Hyemi Song Design Lab

package
{
    import flash.display.Sprite;
    import flash.events.Event;
   
    import org.papervision3d.cameras.Camera3D;
    import org.papervision3d.objects.primitives.Plane;
    import org.papervision3d.render.BasicRenderEngine;
    import org.papervision3d.scenes.Scene3D;
    import org.papervision3d.view.Viewport3D;

[SWF (width="640", height="480", frameRate="36", backgroundColor="0xEEEEEE")] //meta tag는 꼭 붙여줍니다.
    public class PV3DTest extends Sprite
    {
        // 1. ViewPort
        private var viewPort:Viewport3D;
        // 2. Scene3D
        private var scene3D:Scene3D;
        // 3. Camera3D
        private var camera3D:Camera3D;
        // 4. BasicRenderEngine
        private var randerEngine:BasicRenderEngine;

        //3D Object
        private var plan:Plane;
       
        public function PV3DTest()
        {
            super();
            //1.ViewPort 만들고 화면에 붙이기
            this.viewPort= new Viewport3D();
            this.addChild(this.viewPort);  //눈에 보이는 것이므로 addChild
            //2.Scene3D 만들기
            this.scene3D= new Scene3D();
            //3.Camera3D 만들기
            this.camera3D= new Camera3D();
            this.camera3D.zoom=40;
            this.camera3D.moveBackward(500);
            //4.RanderEngine 만들기
            this.randerEngine= new BasicRenderEngine();

            //3D Object 만들기
            this.plan= new Plane();
            this.scene3D.addChild(this.plan); //눈에 보이는 것이므로 addChild
           
            this.addEventListener(Event.ENTER_FRAME, onEnter);
        }
         private function onEnter(e:Event):void
         {
             this.plan.rotationY++;
             this.randerEngine.renderScene(this.scene3D, this.camera3D, this.viewPort );
         }
     
    }//class
}//package

package timo.pv3d
{
    import flash.display.Sprite;
    import flash.events.Event;
   
    import org.papervision3d.cameras.Camera3D;
    import org.papervision3d.render.BasicRenderEngine;
    import org.papervision3d.scenes.Scene3D;
    import org.papervision3d.view.Viewport3D;

    public class Base3D extends Sprite
    {
        public var viewPort3D: Viewport3D;
        public var scene3D: Scene3D;
        public var camera3D: Camera3D;
        public var renderEngine: BasicRenderEngine;       
       
        public function Base3D(  width: Number = 640,
                                                height: Number = 480,
                                                autoScaleToStage: Boolean = false,
                                                interactive: Boolean = false )
        {
            super();
            // 1. viewPort
            this.viewPort3D = new Viewport3D( width,height, autoScaleToStage, interactive );
            this.addChild( this.viewPort3D );
            // 2. stage
            this.scene3D = new Scene3D();
            // 3. camera
            this.camera3D = new Camera3D();
            this.camera3D.zoom = 40;
            this.camera3D.moveBackward( 500 );
            // 4. render
            this.renderEngine = new BasicRenderEngine();
            // 5. 매 프레임마다 렌더링..
            this.addEventListener( Event.ENTER_FRAME, onEnter );
        }
        private  function  onEnter( e: Event ): void
        {
            this.renderEngine.renderScene( this.scene3D, this.camera3D, this.viewPort3D );
        }
       
    }//class
}//package

package
{
    import flash.display.Sprite;
    import flash.events.Event;
   
    import org.papervision3d.cameras.Camera3D;
    import org.papervision3d.materials.ColorMaterial;
    import org.papervision3d.objects.primitives.Plane;
    import org.papervision3d.objects.primitives.Sphere;
    import org.papervision3d.render.BasicRenderEngine;
    import org.papervision3d.scenes.Scene3D;
    import org.papervision3d.view.Viewport3D;
   
   

[SWF (width="640", height="480", frameRate="36", backgroundColor="0xEEEEEE")] //Meta tag는 꼭 써줍니다.
    public class PV3Test1 extends Sprite
    {
        //1. viewPort
        private var viewPort:Viewport3D;
        //2.Sceane3D
        private var scene3D:Scene3D;
        //3.camera
        private var camera3D:Camera3D;
        //4.randerEngine 위 네가지 요소가 기본적으로 필요한 필수사항이므로 머리에 기억하고 있어야 한다.
        private var randerEngine:BasicRenderEngine;
       
        private var plan:Plane;
       
        public function PV3Test1()
        {
            super();
           
            //1. viewPort 만들고 화면에 붙이기::스프라이트를 상속받았으므로 눈에보인다.
            this.viewPort= new Viewport3D(640,480,false,false);
           // autoscale은 화면에 꽉 채울 것인지를 묻는 것임 (false가 기본)
           //interactive는 인터렉션이 가능하도록 할 것인지를 묻는 것임
            this.addChild(this.viewPort);
           
            //this.viewPort.scaleX=2; //기준점을 기준으로 화면 스케일을 쭉~ 늘리는 것임
            //화면전환을 하고 싶다면 뷰포트 2개를 만들어서 애드차일드를 번갈아 가면서 한다.
           
            //2.Sceane3D 만들기
            this.scene3D= new Scene3D();
           
           
            //3.camera 만들기
            this.camera3D= new Camera3D();
            this.camera3D.zoom=40;
            this.camera3D.moveBackward(500);
           
           
            //4.randerEngine 만들기
            this.randerEngine= new BasicRenderEngine();
       

            //3D 오브젝트 만들기
            // 뼈대 이외의 속성들은 material이라는 것으로  컨트롤 한다. (material은 plane 윗라인에 쓰자)
            var material:ColorMaterial= new ColorMaterial(0xFF0000);
            material.doubleSided=true;
           
           
            this.plan= new Plane(material); //뼈대를 만드는 것 !!!!!
            this.scene3D.addChild(this.plan);
   
           
            this.addEventListener(Event.ENTER_FRAME, onEnter);
        }
       
   
   
         private function onEnter(e:Event):void
         {
             this.plan.rotationY++;
             this.randerEngine.renderScene(this.scene3D, this.camera3D, this.viewPort );
         }
       
    }
}

package
{
    import flash.events.Event;
   
    import org.papervision3d.materials.ColorMaterial;
    import org.papervision3d.objects.DisplayObject3D;
    import org.papervision3d.objects.primitives.Plane;
   
    import timo.pv3d.Base3D;

[ SWF (width="640", height="480", frameRate="36", backgroundColor="0xEEEEEE")]//꼭써주자!!
    public class PV3DTest2 extends Base3D
    {
        private var plane:Plane;
        private var plane2:Plane;
        private var planeContainer:DisplayObject3D;
       
        public function PV3DTest2(width:Number=640, height:Number=480, autoScaleToStage:Boolean=false, interactive:Boolean=false)
        {
            //부모클래스의 생성자 호출  base3d의 것 모두 가짐
            super(width, height, autoScaleToStage, interactive);
            //3D 객체 생성하기
            this.createObject3D();
            //매 프래임마다 할 일 (객체변화주기)
            this.addEventListener(Event.ENTER_FRAME, onEnter);
        }
       
       
      private function createObject3D():void
      {
          //채울물질 만들기
          var material:ColorMaterial= new ColorMaterial(0xFF99999);
          var material2:ColorMaterial= new ColorMaterial(0xFFF078);
          //material.doubleSided=true;  //2개의 plane을 만들 것이므로 더블사이드일 필요가 없으니 지워준다.
         
          //물질이 채워진 면 만들기
          this.plane= new Plane(material); //material을 꼭 넣어주어 해당 요소를 적용시킨다.
          this.plane2= new Plane(material2); //material을 꼭 넣어주어 해당 요소를 적용시킨다.
          this.plane.rotationY=180; //2개의 plane의 등이 맡닿을 수 있도록 한쪽면을 180도로 회전시킨다.
         
          //this.scene3D.addChild(this.plane);
          //this.scene3D.addChild(this.plane2);
          this.planeContainer= new DisplayObject3D();
          this.scene3D.addChild(this.planeContainer);
         
          this.planeContainer.addChild(this.plane);
          this.planeContainer.addChild(this.plane2);
         
         
      }
      private function onEnter(e:Event):void
        {
        //this.plane.rotationY+=10;
        //this.plane2.rotationY+=10;
        this.planeContainer.rotationY+=10;
       
        }
    }//class
}//package

/*
과정
1. case로 활용할 planeContainer라는 변수를 선언한다.
2. plane을 2개 만들어 2개의 material로 각각 다른 색을 입힌다.
3. 두개의 plane을 planeContainer에 담고 planeContainer를 회전시켜준다. 즉 두가지 오브젝트를 한 case에 넣고 case 자체를
회전하는 것이다.

package
{
    import flash.events.Event;
   
    import org.papervision3d.materials.ColorMaterial;
    import org.papervision3d.objects.DisplayObject3D;
    import org.papervision3d.objects.primitives.Plane;
   
    import timo.pv3d.Base3D;

    [ SWF( width="640", height="480", frameRate="36", backgroundColor="0xEEEEEE")]
    public class PV3DTest3 extends Base3D
    {       
        public function PV3DTest3( width:Number=640, height:Number=480, autoScaleToStage:Boolean=false, interactive:Boolean=false)
        {
            // 부모클래스의 생성자 호출..
            super(width, height, autoScaleToStage, interactive);
                       
            // 3D 객체 생성하기
            this.createObject3D();

            // 매 프레임마다 할 일... {객체변화주기}
            this.addEventListener( Event.ENTER_FRAME, onEnter );
        }           
       
        private  var planeContainer: DisplayObject3D;
        private  var plane1: Plane;
        private  var plane2: Plane;
                   
        private function createObject3D(): void
        {
            // 채울 물질 만들기
            var material1: ColorMaterial = new ColorMaterial( 0xFF9900 );
            var material2: ColorMaterial = new ColorMaterial( 0x0000FF );
                       
            // 물질이 채워진 면 만들기
            this.plane1 = new Plane( material1, 400, 400 );
            this.plane2 = new Plane( material2, 400, 400 );
            //
            this.plane1.x = 200;
            this.plane2.x = 200;           
            this.plane2.rotationY = 180;           
           
            this.planeContainer = new DisplayObject3D();
            this.scene3D.addChild( this.planeContainer );
           
            this.planeContainer.addChild( this.plane1 );
            this.planeContainer.addChild( this.plane2 );                   
        }
        private function onEnter( e: Event ): void
        {
            this.planeContainer.rotationY += 10;
        }
       
    }
}
/*
회전의 중심을 바꾸려면 DisplayObject3D를 Sprite 처럼 활용하자
flash stage와는 다르게 PV3D에서 오브젝트의 중심은 기본적으로 오브젝트의 중심이다.
그러므로 가로 세로길이가 각 400인 오브젝트에서는 그 중심에서 200만큼 증가시키면
한쪽 변을 중심으로 도는 모션을 구현할 수 있다.

package
{
    import flash.display.BitmapData;
    import flash.events.Event;

    import org.papervision3d.materials.BitmapMaterial;
    import org.papervision3d.objects.primitives.Sphere;
   
    import timo.pv3d.Base3D;
   
[ SWF (width="640", height="480", frameRate="36", backgroundColor="0xEEEEEE")]//꼭써주자!!
    public class PV3DTest4 extends Base3D
    {
        public function PV3DTest4(width:Number=640, height:Number=480, autoScaleToStage:Boolean=false, interactive:Boolean=false)
        {
            super(width, height, autoScaleToStage, interactive);
           
            this.createObject3D();
            this.addEventListener(Event.ENTER_FRAME, onEnter);
        }
        private var earth:Sphere;
       
        private function createObject3D(): void
        {
           
            var bitmapData:BitmapData= new BitmapData(400,300,false,0);
            bitmapData.perlinNoise( 128,128,8,12345, true, true); //네번째 트루는 말렸을 때 끝이 매끄럽게 연결하는것
        //  bitmapData.perlinNoise( 128,128,8,12345, false, true);
           
           
           
            var material:BitmapMaterial = new BitmapMaterial(bitmapData);
            this.earth= new Sphere(material, 300,20,20) //껍질, 반지름 , 가로세로등분
            this.scene3D.addChild(this.earth);
        }
       
        private function onEnter(e:Event):void
        {
            this.earth.rotationX+=2;
            this.earth.rotationY+=3;
        }
       
        }
    }

<변경사항>
Object3D를 만들기 위해 함수 createObject3D를 만든다.
perlinNoise를 쓰기위해 bitmapData를 상속받는다.

package
{
    import flash.events.Event;
   
    import org.papervision3d.materials.BitmapFileMaterial;
    import org.papervision3d.objects.primitives.Sphere;
   
    import timo.pv3d.Base3D;
   
[ SWF (width="640", height="480", frameRate="36", backgroundColor="0xEEEEEE")] //꼭써주자!!
    public class PV3DTest5 extends Base3D
    {
        public function PV3DTest5(width:Number=640, height:Number=480, autoScaleToStage:Boolean=false, interactive:Boolean=false)
        {
            super(width, height, autoScaleToStage, interactive);
           
            this.createObject3D();
            this.addEventListener(Event.ENTER_FRAME, onEnter);
        }
        private var earth:Sphere;
       
        private function createObject3D(): void
        {
           
        // var bitmapData:BitmapData= new BitmapData(400,300,false,0);
       //  bitmapData.perlinNoise( 128,128,8,12345, true, true); //네번째 트루는 말렸을 때 끝이 매끄럽게 연결하는것
       //  bitmapData.perlinNoise( 128,128,8,12345, false, true);
           
           
           
            var material:BitmapFileMaterial = new BitmapFileMaterial ("./img/img0.jpg");
            this.earth= new Sphere(material, 300,20,20) //껍질, 반지름 , 가로세로등분
            this.scene3D.addChild(this.earth);
        }
       
        private function onEnter(e:Event):void
        {
            this.earth.rotationX+=2;
            this.earth.rotationY+=3;
        }
       
        }
    }

package
{
    import flash.events.Event;
   
    import org.papervision3d.materials.BitmapFileMaterial;
    import org.papervision3d.objects.DisplayObject3D; 
    import org.papervision3d.objects.primitives.Sphere;
   
    import timo.pv3d.Base3D;

    [ SWF( width="640", height="480", frameRate="36", backgroundColor="0xEEEEEE" ) ]
    public class PV3DTest6 extends Base3D
    {       
        public function PV3DTest6(width:Number=640, height:Number=480, autoScaleToStage:Boolean=false, interactive:Boolean=false)
        {
            super(width, height, autoScaleToStage, interactive);
           
            this.createObject3D();
            this.addEventListener( Event.ENTER_FRAME, onEnter );
        }
       
        private  var   earth: Sphere;
        private  var   moon: Sphere;
        private  var   moonContainer: DisplayObject3D;
               
        private function  createObject3D(): void
        {   
            // 지구 만들기        
            var material1: BitmapFileMaterial = new BitmapFileMaterial( "./img/world.jpg" );               
            this.earth = new Sphere( material1, 300, 12, 12 );
            this.scene3D.addChild( earth );
            this.earth.rotationZ = -20;
           
            // 달 만들기
            var material2: BitmapFileMaterial = new BitmapFileMaterial( "./img/img1.jpg" );
            this.moon = new Sphere( material2, 50, 8, 8 );
            this.moon.x = 450;
           
            // 달을 화면에 붙이기 { moonContainer - moon }
            this.moonContainer = new DisplayObject3D();
            this.moonContainer.rotationZ = -25;           
            this.moonContainer.addChild( moon );           
            this.scene3D.addChild( this.moonContainer );               
        }
       
        private  function onEnter( e: Event ): void
        {
            this.earth.rotationY += 1;                        // 지구 자전   
            this.moonContainer.rotationY += 2;            // 달이 지구를 중심으로 공전
            this.moon.rotationY += 1;                        // 달 자전
            // this.earth.rotationX += 3;
           
        }       
    } // class
} // package

과정
moon의 case역할을 하게 될 moonContainer 변수 만들기 ( DisplayObject3D 임포트)
earth와  moon 변수 생성하고 각각 material 처리
오브젝트인 moon의 중심점 x위치를 450 만큼 증가 (earth와의 실질적인 거리차이)
moon을 moonContainer 에 넣기
moonContainer를 earth를 중심으로 공전하도록 함
earth를 자전하도록 함

moonContainer에 moon을 넣었기 때문에 earth와 rotationY 를 공유할 수 있는 것임
moonContainer를 쓰지 않았다면 각기 다른 기준점으로 공전/자전을 해야함
그렇게 되면  오브젝트가 많아질 경우 각각 기준점이 다르기 때문에 컨트롤하기가 어려워짐
그러므로 컨테이너를 적극 활용하여 움직임 컨트롤를 쉽게 해야함.

package
{
    import flash.events.Event;
   
    import org.papervision3d.materials.BitmapFileMaterial;
    import org.papervision3d.objects.DisplayObject3D;
    import org.papervision3d.objects.primitives.Sphere;
   
    import timo.pv3d.Base3D;

    [ SWF( width="640", height="480", frameRate="36", backgroundColor="0xEEEEEE" ) ]
    public class PV3DTest7 extends Base3D
    {       
        public function PV3DTest7(width:Number=640, height:Number=480, autoScaleToStage:Boolean=false, interactive:Boolean=false)
        {
            super(width, height, autoScaleToStage, interactive);
           
            this.createObject3D();
            this.addEventListener( Event.ENTER_FRAME, onEnter );
        }
       
        private  var   earth: Sphere;
        private  var   moon: Sphere;
        private  var   moonContainer: DisplayObject3D;
               
        private function  createObject3D(): void
        {   
            // 지구 만들기        
            var material1: BitmapFileMaterial = new BitmapFileMaterial( "./img/world.jpg" );               
            this.earth = new Sphere( material1, 300, 12, 12 );
            this.scene3D.addChild( earth );
            this.earth.rotationZ = -20;
           
            // 달 만들기
            var material2: BitmapFileMaterial = new BitmapFileMaterial( "./img/img1.jpg" );
            this.moon = new Sphere( material2, 50, 8, 8 );
            this.moon.x = 450;
           
            // 달을 화면에 붙이기 { moonContainer - moon }
            this.moonContainer = new DisplayObject3D();
            this.moonContainer.rotationZ = -25;           
            this.moonContainer.addChild( moon );           
            this.scene3D.addChild( this.moonContainer );               
        }
       
        private  function onEnter( e: Event ): void
        {
            this.earth.rotationY += 1;                        // 지구 자전   
            this.moonContainer.rotationY += 2;            // 달이 지구를 중심으로 공전
            this.moon.rotationY += 1;                        // 달 자전
            // this.earth.rotationX += 3;
           
            this.camera3D.x += 0.01 * ( 2000 - this.camera3D.x );
            this.camera3D.z += 0.01 * ( 2000 - this.camera3D.z );
            this.camera3D.y += 0.01 * ( 2000 - this.camera3D.y );
            this.camera3D.lookAt( this.earth );  
 //이차원에서는 좌우상하로 돌아보기만 하면 되지만 삼차원에서는 좌우상하로 바라보고 / 카메라의 위치도 틀어야 한다.
 //어려운 프로세스이므로 기본적으로 lookAt(특정개체) 를 제공한다.
 // lookAt(특정개체)를 쓰면 특정개체의 움직임을 화면 정면으로 바라본 채 카메라가 움직인다. 즉 특정 개체는 항상 화면의 중앙에 놓이게 된다. 특정 개체가 절대기준이 되는 것임.  lookAt(특정개체)을 dimmed시키고 실험해보면 차이점을 알수 있다.
        }       
    } // class
} // package

package
{
    import flash.display.Bitmap;
    import flash.display.Sprite;
   
[SWF (width="550", height="400", frameRate="36", backgroundColor="0x666666")]
    public class EmbedTest1 extends Sprite
    {
       
        //[ Embed ( source="./img/img0.jpg")] public var ImgClass0:Class; 이와 같은 것을 2줄로 한것
       
        //img0이라는 쏘스 이미지를 포함시키고 그것을 imgClass0라는 이름으로 클라스로 만들겠다.
        [ Embed ( source="./img/img0.jpg")]
        public var ImgClass0:Class;
       
        [ Embed ( source="./img/img1.jpg")]
        public var ImgClass1:Class;
          
        public function EmbedTest1()
        {
            super();
           
            //Embed로 등록한 ImgClass0을 생성하고 Bitmap형태로 저장하시오.   
            var img:Bitmap= new ImgClass0() as Bitmap;
            this.addChild(img);
           
            var img2:Bitmap= new ImgClass1() as Bitmap;
            this.addChild(img2);
           
        }
       
    }//class
}//package

package
{
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.filters.BlurFilter;
    import flash.geom.ColorTransform;
    import flash.geom.Matrix;
    import flash.geom.Point;
    import flash.text.TextField;

[SWF (width="550", height="400", frameRate="36", backgroundColor="0xEEEEEE")]
    public class BitmapTest2 extends Sprite
    {
        private var clip:PolygomClip= new PolygomClip();

       
        private var bitmapData:BitmapData= new BitmapData(550,400,false,0);
        private var bitmap:Bitmap= new Bitmap(bitmapData);
       
        public function BitmapTest2()
        {
            super();
           
            this.addChild(bitmap);
            this.addEventListener(Event.ENTER_FRAME, onEnter);
           
        }
        private function onEnter(e:Event):void
        {
            //행렬
            //a:가로확대, d:세로확대, b, c ==>기울임//tx:x위치, ty:y위치
           
            var matrix:Matrix= new Matrix();
            matrix.a=matrix.d=2*Math.random();
            matrix.tx=550*Math.random();
            matrix.ty=400*Math.random();
           
            //색상을 랜덤으로...
            var colorTransform:ColorTransform= new ColorTransform();
            colorTransform.color=0xFFFFFF*Math.random();
           
            this.bitmapData.draw(this.clip,matrix,colorTransform);
           
            var blur:BlurFilter=new BlurFilter(4,4,1);
            bitmapData.applyFilter(bitmapData, bitmapData.rect, new Point(1,0), blur);
           
           
            //this.bitmapData.draw(this.clip, matrix, colorTransform);
           
            //메트릭스: 위치나 크기를 조절하는,컬러트렌스폼 색을 바꾸는 것 ㄴ
        }
       
    }
}

package
{
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.filters.BlurFilter;
    import flash.geom.ColorTransform;
    import flash.geom.Matrix;
    import flash.geom.Point;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
   
    [ SWF( width="550", height="400", frameRate="36", backgroundColor="0xEEEEEE")]
    public class BitmapTest2 extends Sprite
    {
        // private  var clip: PolygonClip = new PolygonClip();
        private  var tf: TextField = new TextField();
       
        private  var bitmapData: BitmapData = new BitmapData( 550, 400, false, 0 );
        private  var bitmap: Bitmap = new Bitmap( bitmapData );
       
        public function BitmapTest2()
        {
            this.tf.autoSize = TextFieldAutoSize.LEFT;
           
            this.addChild( bitmap );
            this.addEventListener( Event.ENTER_FRAME, onEnter );
        }
        private function onEnter( e: Event ): void
        {
            tf.text = Math.random().toString();           
            // 행렬
            //    a: 가로확대,  d: 세로확대,  b,   c ==> 기울임// tx: x 위치,  ty: y 위치  
            var matrix: Matrix = new Matrix();
            matrix.a = matrix.d = 2*Math.random();
            matrix.tx = 550 * Math.random();
            matrix.ty = 400 * Math.random();
           
            // 색상을 랜덤으로..
            var colorTransform: ColorTransform = new ColorTransform();
            colorTransform.color = 0xFFFFFF * Math.random();   

            // 객체 새롭게 그리기        
            this.bitmapData.draw( this.tf, matrix, colorTransform );
           
            // 필터 적용
            var blur: BlurFilter = new BlurFilter( 2, 2, 1 );
            bitmapData.applyFilter( bitmapData, bitmapData.rect, new Point( 1, 0 ), blur );           
        }
    }
}


//this.bitmapData.draw(this.clip, matrix, colorTransform);
// 객체 색상은  ColorTransform으로 변경한다..
//matrix: 위치나 크기를 조절하는 것

package
{
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Sprite;
    import flash.text.TextField;


[SWF (width="550", height="400", frameRate="36", backgroundColor="0xEEEEEE")]
    public class BitmapTest1 extends Sprite
    {
        [ Embed ( source="./img/img2.jpg")]
        private var ImgClass:Class;
       
       
        private var bitmapData:BitmapData= new BitmapData(550,400,false,0x000000);
        private var bitmap:Bitmap= new Bitmap(bitmapData);

       
     private var tf:TextField= new TextField;
       
        public function BitmapTest1()
        {
            super();
            var img:Bitmap=  new ImgClass() as Bitmap;
       
           
            this.addChild(bitmap);
            bitmap.y=20;
            bitmapData.draw(img);
           
            //디스플레이 오브젝트를 상속받았으므로 비트맵은 마우스 이벤트 쓸 수 없음
            //코드힌트에도 없음 스프라이트 하나 만들고 비트맵을 넣고 스프라이트를 이동시키면 됨
           
            //텍스트 필드 붙이기
            this.addChild(tf);
            tf.height=19;
            tf.border=true;
           
        }
       
    }
}

package
{
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.text.TextField;

    [ SWF( width="550", height="400", frameRate="36", backgroundColor="0xEEEEEE")]
    public class BitmapTest1 extends Sprite
    {
        [ Embed( source="./img/img2.jpg")]
        private  var  ImgClass: Class;
       
        private  var  bitmapData: BitmapData = new BitmapData( 550, 400, false, 0x000000 );
        private  var  bitmap: Bitmap = new Bitmap( bitmapData );
        private  var  bitmapCase: Sprite = new Sprite();
       
        private  var  tf: TextField = new TextField();
       
        public function BitmapTest1()
        {
            super();           
            var img: Bitmap = new ImgClass() as Bitmap;                                   
            this.addChild( bitmapCase );
            bitmapCase.addChild( bitmap );
            bitmapCase.y = 21;           
            bitmapData.draw( img );       
           
            // 텍스틀 필드 붙이기
            this.addChild( tf );
            tf.height = 19;
            tf.border = true;
           
            bitmapCase.addEventListener( MouseEvent.CLICK, onClick );
        }       
        private function onClick( e: MouseEvent ): void
        {
            // 0xAARRGGBB
            var rgb: uint = this.bitmapData.getPixel( bitmapCase.mouseX, bitmapCase.mouseY );
            this.tf.text = rgb.toString( 16 ).toUpperCase();
            this.tf.textColor = rgb;
        }
    }
}

// 현재 화면 카피하는 방법 ::: 
    // 1. BitmapData 생성
    // 2. BitmapData를 보여줄  Bitmap을 생성하고 화면에 붙이기
    // 3. BitmapData.draw( 카피할화면 )
//비트맵데이타 비트맵 비트맵 케이스 각각 이유와 역할 을 잘 알아야 한다.




// 비트맵
/*
    - BitmapData -> Object
    - Bitmap -> DisplayObject
    - Sprite
   
    화면을 복제하려면, BitmapData.draw()
    눈내리는 효과에서 에벡같은 효과를 주고 싶으면 현재의 벡터 기반이 아닌 비트맵으로 전환해준다.

    
          var img: Bitmap = new ImgClass() as Bitmap;    비트맵을 ImgClass라는 이름으로 지정                               
          this.addChild( bitmapCase );                                비트맵케이스를 this에  addChild
          bitmapCase.addChild( bitmap );                         bitmap을 비트맵케이스에 addChild
          bitmapCase.y = 21;                                           비트멥케이스(비트멥과 비트멥데이터를 포함하고 있다)를 21만큼 y축이동
          bitmapData.draw( img );                                img를 그리기

=>bitmapCase를 쓴 이유는
마우스로 이미지를 찍었을 때 이미지의 좌표값의 기준을 stage가 아니라 이미지 좌표값으로 하여 정확한 컬러값을 얻기위함이다.

*/

package
{
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Sprite;

[ SWF( width="550", height="400", frameRate="36", backgraundColor="0xEEEEEE")]
    public class BitmapTest extends Sprite
    {
        [ Embed( source ="./img/img0.jpg" )]
        private var ImgClass:Class;
       
       // 이미지 정보를 담고 있는 데이터 객체 : Object 상속받음..
        private var bitmapData: BitmapData= new BitmapData(550,400,false, 0xFF0000 );
       
      // 이미지 정보를 담고있는 bitmapData로부터 이미지를 보여주게 하는... decoder....
      // DisplayObject 상속
        private var bitmap:Bitmap= new Bitmap( bitmapData );
       
        public function BitmapTest()
        {
            super();
           
            var img: Bitmap = new ImgClass() as Bitmap;
           
            this.addChild(bitmap);
            bitmapData.draw(img); //비트맵 안에 비트맵데이타를 그려라
        }
       
    }//class
}//package

    // 실제 이미지 정보를 담고 있는 것은  aaa.jpg 처럼.. 파일..
    // 화면에 이미지를 보여주게 되는 것은... : 포토샵이나 allsee, 이미지편집툴이다..!!
   
    // BitmapData :: 2차원 배열 형태의 데이터 파일로 생각하고
    // Bitmap :: BitmapData의 정보를 읽어서 화면에 표시해주는 객체

package timo.effect
{
    import flash.display.Sprite;
    import flash.events.Event;

    public class Bubble extends Sprite
    {
        private  var  clip: BubbleClip = new BubbleClip();
       
        public  var  vx: Number = 1;
        public  var  vy: Number = 1;

        //public var topBound:Number=0;
        //public var rightBound:Number=800;
        //public var bottonBound:Number=400;       

        public  static  var  topBound: Number = 0;
        public  static  var  rightBound: Number = 800;
        public  static  var  bottomBound: Number = 400;
       
        public  static  var  resistance: Number = 0.95;
        public  static  var  gravity: Number = 0.2 ;       
        public function Bubble()
        {
            super();
            this.setLayout();
        }
        private function setLayout(): void
        {
            this.addChild( clip );   
        }
        // 움직임 명령이 주어지면, 매 프레임마다 할 액션 등록하기
        public  function  startMove(): void
        {
            this.addEventListener( Event.ENTER_FRAME, onEnter );   
        }
        // 매 프레임마다... 할 일..
        private function onEnter( e: Event ): void
        {
            this.x = this.x + this.vx;
            this.y = this.y + this.vy;           

            //vx,vy가 변하지 않으면 등속도 운동...
            //-를 이용하면 언젠가는 반대로 움직여야 한다.
            //빙판과 같은 움직임 서서히 줄어드는 것은 곱하기로 한다.
            this.vx = this.vx * Bubble.resistance; //공통으로 사용하는 것이므로 위에서 static처리 해준다.
            //this.vx.=this.vx*0.98;
            this.vy = this.vy + Bubble.gravity;
                       
            // 영역 바깥으로 나가면.. 사라지기
            if( this.x > Bubble.rightBound || this.y > Bubble.bottomBound || this.y < Bubble.topBound )
            {
                this.removeEventListener( Event.ENTER_FRAME, onEnter );
                parent.removeChild( this );
            }
        }
    } // class
} // package

package
{
    import flash.display.Sprite;
    import flash.events.Event;
   
    import timo.effect.Bubble;

    [ SWF( width="800", height="400", frameRate="36", backgroundColor="0x000000")]
    public class BubbleTest extends Sprite
    {
        public function BubbleTest()
        {
            super();
            this.addEventListener( Event.ENTER_FRAME, onEnter );
        }
        private function onEnter( e: Event ): void
        {
            var  bubble: Bubble = new Bubble();
           
            bubble.x = -20;
            bubble.y = 200;
            bubble.width = bubble.height = 5 + 30 * Math.random();
            bubble.vx = 20 + 20 * Math.random();        // x 속도 : 20 ~ 40
            bubble.vy = -3 + 6 * Math.random();        // y 속도 : -3 ~ 3
           
            this.addChild( bubble );
           
            bubble.startMove();
        }
       
    }
}

눈내리는 효과

컴퓨터 bit :전기가 충전 / 방전 1,0
2bit ::00/01/10/11
8bit ::00110010 ---->1byte 0~256가지의 정보를 저장할 수 있다.
int::-20억~20억---->4byte
number는 8byte

public var vx:Number=1;  ------------>8byte
public var vy:Number=1;  ------------>8byte
public var ground:Number=400; ----->8byte
총 24byte

주로 변수들이 메모리를 차지한다.
그러므로 공유용인지 개별용인지를 구분하여 공유용인 것은  static으로 바꿔주어 메모리 할당량을 줄여준다.
실험을 해보면 static을 쓸때와 그렇지 않을 때 퍼포먼스의 차이가 많이 나게 되는 것을 알 수 있다.

package timo.effect
{
    import flash.display.Sprite;
    import flash.events.Event;

    public class Snow extends Sprite
    {
        private  var  clip: SnowClip = new SnowClip();
       
        // 속도 변수 :: 외부에서 설정할 수 있도록... public으로 설정
       //모든 눈의 속도는 다르므로 개별적으로 가져야한다.
        public  var  vx: Number = 1;                // 개별
        public  var  vy: Number = 1;                // 개별
       
        // 공유변수는 static 변수로 설정 --> 클래스 변수
       //모든 눈이 도달하는 ground위치는 같으므로  ground 변수는  공유해도 된다.
        //public  var  ground: Number = 400;    // 공유변수 !!!!!  Snow.ground (아래의 static 변수와 비교하며 실험해본다.)
        public  static  var  ground: Number = 400;    // 공유변수 !!!!!  Snow.ground
        
        //메서드는 따로 저장이 되므로 그냥 두고 변수 부분을 최대한 줄여보자!!!!!!!
        //공유변수는 static 변수로 설정 ====>클래스 변수
      
        // static 함수 --->  사용의 편의성  Math.random()
        // static 변수 --->  공유의 목적...!!
         
        public function Snow()
        {
            super();
            this.setLayout();
            this.addEvent();
        }
       
        private  function  setLayout(): void
        {
            this.addChild( clip );           
        }
       
        private  function  addEvent(): void
        {           
        }
       
        // 이 함수가 호출되면, 매 프레임마다 움직이기 시작...!!
        public  function  startMove(): void
        {
            this.addEventListener( Event.ENTER_FRAME, onEnter );
        }
       
        private function onEnter( e: Event ): void
        {
            this.x = this.x + this.vx;
            this.y = this.y + this.vy;
          
            // 땅으로 떨어지고나면, 매 프레임마다 할 일 제거하고, 자신은 parent로부터 삭제
            // removeChild할 경우, (하고있는 일을 멈추지 않고 잠깐 강의실을 나가있어라! 와 같은 뜻임)
            //(removeChild의 경우는 계속 Event.ENTER_FRAME은 여전히 작동중이므로  Event도 지워준다.)
                // 1. 애니메이션이 있으면 stop()시키고,
                // 2. EnterFrame 이벤트 삭제하기 
            if( this.y > Snow.ground ){
                this.removeEventListener( Event.ENTER_FRAME, onEnter );
                parent.removeChild( this );
            }
        }
               
    } // class
} // package

package
{
    import flash.display.Sprite;
    import flash.events.Event;
   
    import timo.effect.Snow;

    [SWF( width="550", height="400", frameRate="36", backgroundColor="0x000000")]
    public class SnowTest extends Sprite
    {       
        public function SnowTest()
        {
            super();
            this.addEventListener( Event.ENTER_FRAME, onEnter );
        }
        private function  onEnter( e: Event ): void
        {
            // 1. 눈 만들기
            var  snow: Snow = new Snow();
            // 2. 초기 위치및 크기 설정
            snow.width     = snow.height = 2 + 10 * Math.random();        // 2 ~ 12
            snow.x             = 550 * Math.random();            // 0 ~ 550
            snow.y             = -20;
            snow.vx            = -2 + 4 * Math.random();        // -2 ~ 2
            snow.vy            = 2 + 4 * Math.random();            // 2 ~ 6
            // 3. 화면에 붙이기
            this.addChild( snow );
            // 4. snow 이동시키기
            snow.startMove();       
        }
       
    } // class
} // package